;
; **********************************************
; * Infrared controlled switchbox              *
; * for ATtiny13, internal clock 1.2 MHz, V1   *
; * (C)2010 by http://www.avr-asm-tutorial.net *
; **********************************************
;
.NOLIST
.INCLUDE "tn13def.inc" ; Headerdatei for ATtiny13 
.LIST
;
; Debug preset
;
.equ debug = 0 ; debug on: 1, off: 0
;
; ============================================
;  H A R D W A R E    I N F O R M A T I O N S 
; ============================================
;
;              ________
;          1 /         |8
;  RESET O--|RES    VCC|--O VCC
;           |    AT    |
;  DR-CS O--|PB3    PB2|--O Relais/SCK
;           |   tiny   |
; DR-SCK O--|PB4    PB1|--O LED/IN/DR-SI/MISO
;           |    13    |
;    GND O--|GND    PB0|--O IR-IN/MOSI
;          4|__________|5
;
; ============================================
;      P O R T S   A N D   P I N S 
; ============================================
;
.equ pbRelO = PORTB2 ; Relais output pin
.equ pbLedO = PORTB1 ; LED output port
.equ pbLedD = DDB1  ; LED output direction port
.equ pbCsO  = PORTB3 ; DR-CS digital resistor CS
.equ pbSckO = PORTB4 ; DR-SCK digital resistor SCK
.equ pbSiO  = PORTB1 ; DR-SI digital resistor SI
.equ pbIrIn = PINB0  ; Infrared-Input
;
; ================================================
;        P R O G R A M    F L O W
; ================================================
;
; Timer0 works with the prescaler at 64 (18.750 Hz)
;   Every 13,653 ms an overflow occurs and
;   - stops eventually running IR-Signal analysis
;   - increases the Timeout-counter, if the relais isd active
;
;
; ================================================
;     C O N S T A N T S  T O   C H A N G E
; ================================================
;
; (none)
;
; =======================================================
;    F I X E D   +   D E R I V E D   C O N S T A N T S
; =======================================================
;
.equ clock = 1200000 ; processor clock
;
; ============================================
;   R E G I S T E R   D E F I N I T I O N S
; ============================================
;
; R0 free for LPM
; Free: R1..R10
.def rPot = R11 ; Status digital pot
.def rPotV = R12 ; Pot value
.def rTO1 = R13 ; Time-Out-Coumnter, Byte 1
.def rTO2 = R14 ; Time-Out-Counter, Byte 2
.def rSreg = R15 ; Register for SREG
.def rmp = R16 ; Multi purpose register
.def rimp = R17 ; Multi purpose register interrupts
.def rFlg = R18 ; Flag register
	.equ bIrAktiv = 0 ; IR-Analysis start
	.equ bIrAdrOk = 1 ; IR-Adress recognised
	.equ bIrCmdOk = 2 ; Command recognised
	.equ bIrBreak = 3 ; Abort due to error
.def rTO3 = R19 ; Time-Out-Counter, Byte 3
.def rTc = R20 ; Timer value
.def rIrC = R21 ; Register for IR-Cmd-Code
.def rIrCL = R22 ; Register for the last recognised IR-Cmd-Code
; frei: R22..R29
; used for LPM
;
; ============================================
;       S R A M   D E F I N I T I O N S
; ============================================
;
; (none)
;
; ==============================================
;   R E S E T   A N D   I N T   V E C T O R S
; ==============================================
;
.CSEG
.ORG $0000
	rjmp Main ; Reset-Vector
	reti ; Int0 Vector
	rjmp PcInt ; PcInt0 Vector
	rjmp Tc0Int ; Tc0Ovf-Int Vector
	reti ; EERDY-Int Vector
	reti ; AnaComp-Int Vector
	reti ; TC0COMPA-Int Vector
	reti ; TC0COMPB-Int Vector
	reti ; WDT-Int Vector
	reti ; ADC-Int Vector
;
; ==========================================
;    I N T E R R U P T   S E R V I C E
; ==========================================
;
; Pin Change interrupt on IR input
;   reads timer, clears timer, sets T-flag
PcInt:
	sbic PINB,pbIrIn ; Input = 0?
	reti ; Input =1, ignore low-to-high transitions
	in rTc,TCNT0 ; read timer
	ldi rimp,1<<PSR10 ; clear timer prescaler
	out GTCCR,rimp
	ldi rimp,0 ; clear timer
	out TCNT0,rimp
	set ; set flag
	reti
; TC0 overflow interrupt
Tc0Int:
	in rSreg,SREG ; save SREG
	ldi rFlg,0 ; clear IR recognition flags
	dec rTO1 ; Timeout-Counter 3,5 seconds
	brne Tc0IntRet
	dec rTO2 ; Timeout-counter 14,9 minutes
	brne Tc0IntRet
	inc rTO3 ; Timeout-counter quarter hours
	cpi rTO3,20 ; 5 hours over?
	brcs Tc0IntRet ; no, not yet
	cbi PORTB,pbRelO ; Relais on
	cbi DDRB,pbLedD ; LED off
	sbi PORTB,pbLedO ; Pull-Up on
Tc0IntRet:
	out SREG,rSreg ; restore SREG
	reti
;
; ============================================
;    M A I N    P R O G R A M M    I N I T
; ============================================
;
Main:
	; Stack init
	ldi rmp,LOW(RAMEND) ; set stack pointer
	out SPL,rmp
	; Clear flags
	clr rFlg
	; Digital pot drivers
	sbi PORTB,pbCsO ; CS high
	sbi DDRB,pbCsO ; CS Output
	cbi PORTB,pbSckO ; SCK Output low
	sbi DDRB,pbSckO ; SCK Output
	cbi PORTB,pbSiO ; SI Output low
	sbi DDRB,pbSiO ; SI Output
	; LED-output off
	sbi PORTB,pbLedO ; LED-port high, pull-up on
	cbi DDRB,pbLedD ; LED-port inactive
	; Relais-output on
	cbi PORTB,pbRelO ; Relais off
	sbi DDRB,pbRelO ; Relais output active
	; Start blinking
	ldi rmp,3 ; blink LED three times
	rcall LedN
	; Start value pot
	rcall ReadPot ; read pot value from EEPROM
	rcall PotTab ; linear to exponential 
	rcall SendPot ; send to pot
	; start timer 0
	clr rmp ; set Mode 0
	out TCCR0A,rmp
	ldi rmp,(1<<CS01)|(1<<CS00) ; prescale by 64
	out TCCR0B,rmp
	ldi rmp,1<<TOIE0 ; interrupts enable
	out TIMSK0,rmp
	; IR-input interrupts enable
	ldi rmp,1<<pbIrIn ; mask for PCINT
	out PCMSK,rmp
	ldi rmp,1<<PCIE ; enable IR-Input int
	out GIMSK,rmp
	; SLEEP enable
	ldi rmp,1<<SE ; Enable sleep
	out MCUCR,rmp
	sei
;
; ============================================
;     P R O G R A M  -  L O O P
; ============================================
;
Loop:
	sleep ; send CPU to sleep
	nop ; Dummy for wake-up
	brts FSet ; Flag set?
	sbis PORTB,pbLedO ; output already active?
	rjmp Loop ; active, ignore button
	sbic PINB,pbLedO ; button pressed?
	rjmp Loop ; button not pressed
OutAn:
	sbi PORTB,pbRelO ; Relais on
	cbi PORTB,pbLedO ; LED on
	sbi DDRB,pbLedD ; LED output active
	clr rTO1 ; clear TimeOut-counter
	clr rTO2
	clr rTO3
	rjmp Loop ; done
FSet: ; Flag is set
	clt ; clear flag
	sbrc rFlg,bIrBreak ; break flag set?
	rjmp Loop ; yes, ignore rest
	mov rmp,rTc ; copy timer value
	sbrc rFlg,bIrAktiv ; start IR analysis?
	rjmp IrAktiv
	; IR analysis not active, wait for first signal
	cpi rmp,230
	brcs Loop ; signal too short
	; IR analysis not active, start recognition
	ldi ZH,HIGH(2*IrAdrTab) ; pointer to IR table
	ldi ZL,LOW(2*IrAdrTab)
	sbr rFlg,1<<bIrAktiv ; set flag aktice
IrAktiv: ; IR analysis is active
	sbrc rFlg,bIrAdrOk ; adress already complete?
	rjmp IrAdrOk ; yes
	lpm R0,Z+ ; read low table adress
	tst R0 ; table value = 0?
	breq IrAktivAdrOk ; adress correct
	cp rmp,R0 ; is value >= lower value
	brcs IrAktivBreak1 ; no, set break
	lpm R0,Z+ ; read higher value
	cp rmp,R0 ; compare
	brcs Loop ; value is fine
IrAktivBreak2: ; too long
.if debug == 1
	subi ZL,Low(2*IrAdrTab)
	lsr ZL
	mov rmp,ZL
	rcall LedN
	ldi rmp,4 ; blink four times
	rjmp IrAktivBreakN
	.endif
IrAktivBreak1:
.if debug == 1
	push rmp
	subi ZL,Low(2*IrAdrTab)
	lsr ZL
	mov rmp,ZL
	rcall LedN
	mov rmp,R0
	rcall LedHex
	pop rmp
	rcall LedHex
	ldi rmp,3 ; blink three times
	rjmp IrAktivBreakN
	.endif
IrAktivBreak3:
	ldi rmp,3
IrAktivBreakN:
	sbr rFlg,1<<bIrBreak ; set break flag
.if debug == 1
	rcall LedN
	.endif
	rjmp Loop
IrAktivAdrOk:
	sbr rFlg,1<<bIrAdrOk ; set adress ok
	ldi rIrC, 0x01 ; start with a one
IrAdrOk:
	cpi rmp,17 ; smaller than low-high level
	brcs IrAktivBreak1
	cpi rmp,45 ; longer than high limit
	brcc IrAktivBreak2
	cpi rmp,30 ; 0 or 1?
	brcc IrAdrOk1 ; shift 1 in
	clc ; shift 0 in
	rjmp IrCmdShift
IrAdrOk1:
	sec
IrCmdShift:
	rol rIrC ; shift carry into code byte
	brcc Loop ; not yet completed
	sbr rFlg,1<<bIrBreak ; set recognition inactive
	cp rIrC,rIrCL ; equal last command?
	breq IrCmdEqu
	mov rIrCL,rIrC
	rjmp Loop
IrCmdEqu:
	cpi rIrC,cOn ; ON command?
	brne IrCmdOff
	sbi PORTB,pbRelO ; relais on
	cbi PORTB,pbLedO ; LED on
	sbi DDRB,pbLedD ; Porttreiber an
	clr rTO1 ; clear timeout counter
	clr rTO2
	clr rTO3
	rjmp IrCmdOk
IrCmdOff:
	cpi rIrC,cOff ; OFF command?
	brne IrCmdVolUp ; no
	cbi PORTB,pbRelO ; relais off
	sbi PORTB,pbLedO ; LED off
	cbi DDRB,pbLedD ; Port driver off
	rjmp IrCmdOk
IrCmdVolUp:
	cpi rIrC,cVol_up ; Volume-Up?
	brne IrCmdVolDwn ; no
	; Volume Up
	inc rPot
	mov rmp,rPot
	cpi rmp,cMaxPot ; value too high?
	brcs IrCmdVolUpOk
	dec rPot ; decrease value
	rjmp Loop ; quit without signal
IrCmdVolUpOk:
	rcall PotTab ; linear to exponential
	rcall SendPot ; send rPotV to pot
	rcall WritePot ; store rPot in EEPROM
	rjmp IrCmdOk
IrCmdVolDwn:
	cpi rIrC,cVol_dwn ; Volume down?
	brne IrCmdUnkn ; no
	; Volume down
	tst rPot
	breq IrCmdVolDwn1
	dec rPot ; volume smaller
	rcall PotTab ; linear to exponential
	rcall SendPot ; send rPotV to pot
	rcall WritePot ; write rPot in EEPROM
	rjmp IrCmdOk
IrCmdVolDwn1:
	rjmp Loop
IrCmdUnkn:
.if debug == 1
	ldi rmp,2
	rcall LedN
	mov rmp,rIrc
	rcall LedHex
	.endif
	rjmp Loop
IrCmdOk:
	ldi rmp,1 ; single blink
	rcall LedN
	rjmp Loop
;
; Table for IR address recognition
;   first byte: signal duration must be equal or higher
;   second byte: signal duration must be smaller
;   End of the table (positive recognition): 0
IrAdrTab:
.db 230,245,17,30,17,30,17,30,17,30,31,45,31,45,31,45,31,45,80,95,0,0
; Beamer codes, H+L	
.equ cVol_dwn = 0b00100001	
.equ cOn = 0b10000010	
.equ cOff = 0b01000010	
.equ cVol_up = 0b10100001
;
; Read pot value from EEPROM
;
ReadPot:
	sbic EECR,EEPE ; wait for EEPROM ready
	rjmp ReadPot
	ldi rmp,63 ; Addres EEPROM
	out EEARL,rmp
	sbi EECR,EERE ; set read bit
	in rPot,EEDR ; read byte
	ldi rmp,0 ; clear address
	out EEARL,rmp
	rcall PotTab ; convert to exponential
	rcall WritePot ; write value to pot
	ret
;
; Write pot value in EEPROM
;
WritePot:
	sbic EECR,EEPE ; wait for EEPROM
	rjmp WritePot
	ldi rmp, (0<<EEPM1)|(0<<EEPM0) ; write mode
	out EECR,rmp
	ldi rmp,63 ; Address EEPROM
	out EEARL,rmp
	out EEDR,rPot
	cli ; stop interrupts
	sbi EECR,EEMPE ; write
	sbi EECR,EEPE
	sei ; enable ints
WritePot1:
	sbic EECR,EEPE ; wait until written
	rjmp WritePot1
	ldi rmp,0x00 ; write adress 0
	out EEARL,rmp
	ret
;
; Write pot value
;
SendPot:
	ldi ZH,0x13 ; command byte for pot
	mov ZL,rPotV ; data byte for pot
	cbi PORTB,pbSiO ; clear SI
	cbi PORTB,pbSckO ; clear SCK
	cbi PORTB,pbCsO ; activate CS
	sec
sendpotbit:
	rol ZL ; one bit left
	rol ZH
	brcs sendpotone
	cbi PORTB,pbSiO ; clear SI
	rjmp sendpotshift
sendpotone:
	sbi PORTB,pbSiO ; set SI
sendpotshift:
	sbi PORTB,pbSckO ; set SCK
	cbi PORTB,pbSckO ; clear SCK
	cpi ZL,0 ; end of transfer?
	clc ; set next bit shifted in
	brne sendpotbit
	cpi ZH,0x80 ; last bit?
	clc ; set next bit shifted in
	brne sendpotbit
	sbi PORTB,pbCsO ; end, clear CS
	sbi PORTB,pbLedO ; LED output inactive
	cbi DDRB,pbLedD ;  Port driver off
	sbis PORTB,pbRelO ; Relais on?
	ret ; nein
	cbi PORTB,pbLedO ; LED output on
	sbi DDRB,pbLedD ; Port driver on
	ret
;
; Output LED signals
;
.if debug == 1
	.equ tlow = 300 ; Duration LED off in ms
	.equ tHigh = 300 ; Duration LED on in ms
	.equ tPause = 500 ; Duration pause at end, max. 500
	.else
	.equ tlow = 160
	.equ tHigh = 80
	.equ tPause = 80
	.endif
.equ nTakt = clock/1000/10 ; clocks per ms
.equ nLow = tLow*nTakt
.equ nHigh = tHigh*nTakt
.equ nPause = tPause*nTakt
LedN: ; output N blink signals, N in rmp
	tst rmp ; rmp = 0?
	brne LedNGo ; no
	ldi rmp,10 ; 0, set to 10
LedNGo:
	ldi ZH,HIGH(nLow) ; off time
	ldi ZL,LOW(nLow)
	sbi DDRB,pbLedD ; port driver on
	sbi PORTB,pbLedO ; LED output high
LedNLow:
	rcall LedNWait ; wait 10*Z clocks
	cbi PORTB,pbLedO ; Led on
	ldi ZH,HIGH(nHigh) ; on time
	ldi ZL,LOW(nHigh)
LedNHigh:
	rcall LedNWait ; wait 10*Z clocks
	sbi PORTB,pbLedO ; Led off
	dec rmp
	brne LedNGo
	ldi ZH,HIGH(nPause)
	ldi ZL,LOW(nPause)
	rcall LedNWait
	sbi PORTB,pbLedO ; Pullup on
	cbi DDRB,pbLedD ; Port driver on
	sbis PORTB,pbRelO ; Relais on?
	ret
	cbi PORTB,pbLedO ; LED-Port on
	sbi DDRB,pbLedD ; Port driver on
	ret
; Wait
LedNWait: ; wait for 10*Z clocks
	nop
	nop
	nop
	nop
	nop
	nop
	sbiw ZL,1
	brne LedNWait
	ret
;
; Display rmp in hex
;
LedHex:
	push rmp ; save original
	swap rmp ; upper to lower nibble
	rcall LedHexN
	pop rmp ; restore original
LedHexN:
	andi rmp,0x0F ; only the lower nibble
	cpi rmp,0x00 ; 0 = 16
	brne LedHexNO
	ldi rmp,0x10
LedHexNO:
	rjmp LedN ; display nibble in hex on LED
;
; Pot value from table
;   Table for exponential charakteristic
;   checks table value in rPot und corrects it
;   translates 0..52 in rPot to pot value in rPotV
;
PotTab:
	mov rmp,rPot ; copy pot value
	cpi rmp,0xFF ; underflow following dec?
	brne PotTab1
	inc rPot ; set underflow to zero
	rjmp PotTab2
PotTab1:
	cpi rmp,cMaxPot ; overflow after inc?
	brcs PotTab2
	ldi rmp,cMaxPot-1 ; load max value
	mov rPot,rmp
PotTab2:
	ldi ZH,HIGH(2*TabPot) ; pointer to table
	ldi ZL,LOW(2*TabPot)
	add ZL,rPot ; add to table value
	ldi rmp,0 ; MSB overflow
	adc ZH,rmp
	lpm rPotV,Z
	ret
TabPot:
.db 0,1,2,3,4,5,6,7,8,9
.db 10,12,14,16,18,20,22,24,26,29
.db 32,35,38,41,44,47,51,55,59,63
.db 67,71,76,81,86,91,96,102,108,114
.db 121,128,135,143,151,160,169,179,189,200
.db 212,225,239,255,255,255
TabPotEnd:
.equ cMaxPot = TabPotEnd-TabPot ; number of values in table
;
; End source code
; Copyright
.db "(C)2010 by Gerhard Schmidt  " ; readable
.db "C(2)10 0yb eGhrra dcSmhdi t " ; wordwise
;