; Loesung Aufgabe 7: EEPROM-Hochzaehler
;
.nolist
.include "tn13def.inc"
.list
;
; Konstanten definieren
.equ cEep = 10 ; Zelle im EEPROM-Speicher
; Verzoegerung durch Schleife
.equ c002 = (1200000/50-8)/4 ; 0,02 s Verzoegerung
.equ c01 = (1200000/10-8)/4 ; 0,1 s Verzoegerung
.equ c02 = (1200000/5-8)/4 ; 0,2 s Verzoegerung
;
; Register definieren
.def rmp = R16 ; Multi-Purpose-Register
.def cnt = R17 ; Zaehler
.def rdl = R24 ; Verzoegerungszaehler, LSB
.def rdh = R25 ; dto., MSB
;
; Initiieren
	ldi rmp,LOW(RAMEND) ; Stapelzeiger
	out SPL,rmp ; setzen
	sbi DDRB,PB0 ; LED-Treiber an
	sbi PORTB,PB0 ; LED aus
	sbi PORTB,PB4 ; Pull-Up Taster an
; Verzoegerung um 0,02 s
	ldi rdh,HIGH(c002) ; 0,02 s
	ldi rdl,LOW(c002)
	rcall Delay ; rufe Unterprogramm
; Eingang abfragen
	clr cnt ; Zaehler auf Null
	sbis PINB,PB4 ; Frage Taster ab
	rjmp Schreiben ; Schreibe Null in EEPROM
; EEPROM lesen
	ldi rmp,cEep ; Adresse der EEPROM-Zelle in Register
	out EEARL,rmp ; in EEPROM-Adressregister schreiben
	sbi EECR,EERE ; Setze Read Enable Bit
	in cnt,EEDR ; Lese Inhalt der Zelle in das Register
; Zaehler um Eins erhoehen
	inc cnt ; increase Zaehler
; Zaehler in EEPROM schreiben
Schreiben:
	sbic EECR,EEPE ; Control ob Schreiben moeglich
	rjmp Schreiben ; Schreiben noch nicht moeglich
	ldi rmp,(0<<EEPM1) | (0<<EEPM0) ; Schreibmodus = 00
	out EECR,rmp ; in Kontrollregister
	ldi rmp,cEep ; Adresse der EEPROM-Zelle in Register
	out EEARL,rmp ; in EEPROM-Adressregister schreiben
	out EEDR,cnt ; Zaehler in Datenregister
	sbi EECR,EEMPE ; setze Write Enable Bit
	sbi EECR,EEPE ; setze programming Enable
; Teste ob cnt gleich Null (sofort schlafen legen)
	tst cnt ; Vergleiche mit Null
	breq Schlafen ; bei Null gleich schlafen legen
; cnt nicht Null, LED cnt mal an- und ausschalten
LedAn:
	cbi PORTB,PB0 ; Led einschalten
	ldi rdh,HIGH(c01) ; Delay 0,1 s
	ldi rdl,LOW(c01)
	rcall Delay ; Delay ausfuehren
	sbi PORTB,PB0 ; LED ausschalten
	ldi rdh,HIGH(c02) ; Delay 0,2 s
	ldi rdl,LOW(c02)
	rcall Delay ; Delay ausfuehren
	dec cnt ; Zaehler um Eins abwaerts
	brne LedAn ; noch nicht Null, noch mal
; Prozessor ausschalten
Schlafen:
   ldi rmp,(1<<SE) | (1<<SM1) ; Power down mode
   out MCUCR,rmp ; in MCU Kontrollregister
   sleep ; Prozessor ausschalten
;
; Unterprogramm Verzoegerungsschleife
Delay: ; LDI=2 Takte, RCALL=3 Takte
   sbiw rdl,1 ; zaehle herunter, 2 Takte
   brne Delay ; noch nicht Null, 1 oder 2 Takte
   ret ; Rueckkehr, 4 Takte
; Anzahl Takte  n = 5 + 4*(c-1) + 3 + 4
;               n = 4*c + 8
; Zaehlkonstante c = (n-8) / 4
;
; EEPROM beim Programmieren initiieren
.ESEG ; in das EEPROM-Segment schreiben
.ORG cEep ; Adresse auf Zelle setzen
.DB 0 ; Null in Zelle schreiben
;