; **************************************************************
; * Akkuloader Version 0.1 for ATmega16 @ 8 Mcs/s clock        *
; * (C)2005 by Gerh.Schmidt info@avr-asm-tutorial.net          *
; **************************************************************
;
.INCLUDE "m16def.inc"
;
; Constants
;
.EQU fclock = 8000000 ; processor clock frequency
.EQU baud = 9600 ; Serial communication baudrate
.EQU cUartTime = 5 ; send system time over Uart any 5 minutes
.EQU cKeyRep = 5 ; number of correct keys until key is accepted
.EQU cUnlVol = 1000 ; default unload threshhold voltage in mV
;
; Register definitions
;
; R0 used as register for flash operations
; R1:R0 used as double register in calculations
; R3:R2 dto.
; R6:R5:R4 used as triple register in calculations
.DEF rKeyLst = R7 ; Last key read
.DEF rKeyRep = R8 ; counter for key repeat
;.DEF rAdcV  = R9  ; Operating voltage mask of the ADC
.DEF rPwmC  = R10 ; PWM counter
.DEF rPwm1S = R11 ; PWM switch value for Channel 1
.EQU cPwm1S = 11  ; Value for calculating channel register
.DEF rPwm2S = R12 ; PWM switch value for Channel 2
.DEF rPwm3S = R13 ; PWM switch value for Channel 3
.DEF rPwm4S = R14 ; PWM switch value for Channel 4
.DEF rSreg  = R15 ; Save SREG during ints
.DEF rmp    = R16 ; Multipurpose register
.DEF rimp   = R17 ; Multipurpose register during interrupts
.DEF rimp1  = R18 ; Multipurpose register during interrupts
.DEF rFlg   = R19 ; Multipurpose flag register
.DEF rFlgD  = R20 ; Display flag register
.DEF rPwmOut= R21 ; Value for Port Out
; Free R22..R23
.DEF rChCL = R24 ; channel counter, LSB
.DEF rChCH = R25 ; dto., MSB
; X (R27:R26) used for purposes outside Ints
; Y (R29:R28) used for ADC channel calculations
; Z (R31:R30) used for purposes outside Ints
;
; Bit definitions for rFlg
.EQU bUartRxLine = 7 ; a complete line has been received
.EQU bLcdOk = 6 ; Lcd is connected and detected ok
; not used: bit 4 and 5
.EQU bMin = 2 ; timer reached 1 Minute
.EQU b32m = 1 ; timer int 4 seconds, 32 Adc conversions complete
.EQU b64Hz = 0 ; timer int 64 Hz tick
;
; Bit definitions for the display flag rFlgD
;
.EQU bUHex = 7 ; display results in hex over Uart (debug)
.EQU bUMoni = 6 ; monitor active channels over Uart
.EQU bURdy = 5 ; results ready for Uart display
.EQU bLRdy = 4 ; results ready for Lcd display
.EQU bLcd3 = 3 ; Display results in line 4
.EQU bLcd2 = 2 ; Display results in line 3
.EQU bLcd1 = 1 ; Display results in line 2
.EQU bLcd0 = 0 ; Display results in line 1
;
;
; Calculated constants
;
.EQU cTC1Prsc = 8 ; TC1 Prescaler value
.EQU cTC1Div = fClock / cTC1Prsc / 64 ; 64 Ints per second
.EQU cTC1CompB = 50 ; Timer compare to start ADC
.EQU cStartAdc = (1<<ADEN)|(1<<ADPS2)|(1<<ADPS1)|(1<<ADPS0); Enable and clock=128
.EQU cRestartAdc = cStartAdc | (1<<ADSC)
.EQU cAdcV = 1<<REFS0 ; Set Adc reference voltage to 5V
.EQU cEepMax = 512/16 ; maximum number of stored akkus in Eeprom = 32
.EQU cCr = $0D ; Carriage return char
.EQU cLf = $0A ; Line feed char
;
; SRAM Positions
;
; Uart SRAM variables
.EQU sUartRxBp = $0060 ; UART Rx Buffer Pointer
.EQU sUartRxBs = $0061 ; Uart Rx Buffer start
.EQU sUartRxBe = $007E ; Uart Rx Buffer end
.EQU sUartCurCh = $007F ; Current Uart Channel
; Channel values
.EQU sCh1UV = $0080 ; Channel 1, minimum unloading voltage
.EQU sCh1LC = $0082 ; Ch 1, load current in mA
.EQU sCh1LW = $0084 ; Ch 1, max work to load in mAh
.EQU sCh1MC = $0086 ; Ch 1, maintain current in mA
.EQU sCh2UV = $0088 ; Ch 2, dto.
.EQU sCh2LC = $008A ; Ch 2, dto.
.EQU sCh2LW = $008C ; Ch 2, dto.
.EQU sCh2MC = $008E ; Ch 2, dto.
.EQU sCh3UV = $0090 ; Ch 3, dto.
.EQU sCh3LC = $0092 ; Ch 3, dto.
.EQU sCh3LW = $0094 ; Ch 3, dto.
.EQU sCh3MC = $0096 ; Ch 3, dto.
.EQU sCh4UV = $0098 ; Ch 4, dto.
.EQU sCh4LC = $009A ; Ch 4, dto.
.EQU sCh4LW = $009C ; Ch 4, dto.
.EQU sCh4MC = $009E ; Ch 4, dto.
; Measuring values
.EQU sAdcE1 = $00A0 ; Adc measuring results, even channels
.EQU sAdcO1 = $00A8 ; dto., odd channels
.EQU sAdcE4 = $00B0 ; Adc sum for 4 seconds, even channels
.EQU sAdcO4 = $00B8 ; dto., odd channels
.EQU sAdcU  = $00C0 ; Voltages, even channels, then odd channels
.EQU sAdcI  = $00D0 ; Load currents in mA
.EQU sAdcC  = $00D8 ; mAh (LSB,MSB)
.EQU sAdcLL1= $00E0 ; mAh LLSB, Channel 1
.EQU sAdcAI1= $00E1 ; accu id, Channel 1
; Channel control
.EQU sState = $00E8 ; Current state of the channels, bits 44332211
		; 00=nothing, 01:unloading, 10:loading, 11:maintaining
.EQU sTimeM = $00E9 ; System time, minutes (0, 15, 30, 45)
.EQU sTimeH = $00EA ; dto., hours
.EQU sTimeD = $00EB ; dto., days
.EQU sLcdCs = $00EC ; LCD cursor position
; Key input
.EQU sKeyNC = $00ED ; Decimal number input position
.EQU sKeyNW = $00EE ; Decimal number in and output word
.EQU sKeyNM = $00F0 ; Decimal number maximum value
.EQU sKeyJR = $00F2 ; Jump adress on number input ready
.EQU sKeyJS = $00F4 ; Jump adress on skip number input
.EQU sKeyJ1 = $00F6 ; Jump adress on key 1
.EQU sKeyJ2 = $00F8 ; dto., key 2
.EQU sKeyJ3 = $00FA ; dto., key 3
.EQU sKeyCh = $00FC ; Selected channel for sets and commands
; LED output
.EQU sLedC  = $00FD ; Led counter
.EQU sLed1  = $00FE ; Led channel 1 compare value
.EQU sLed2  = $00FF ; dto., channel 2
.EQU sLed3  = $0100 ; dto., channel 3
.EQU sLed4  = $0101 ; dto., channel 4
; EEPROM buffer
.EQU sEepB  = $0102 ; EEPROM buffer for an akku record, 16 bytes
.EQU sEAId  = $0102 ; EEPROM Akku Id
.EQU sESize = $0103 ; EEPROM Akku size = A0..A3
.EQU sENCL  = $0104 ; EEPROM nominal capacity LSB
.EQU sENCM  = $0105 ; dto., MSB
.EQU sENLL  = $0106 ; EEPROM number of full loads, LSB
.EQU sENLM  = $0107 ; dto., MSB
.EQU sENRL  = $0108 ; EEPROM rest capacity in mAh, LSB
.EQU sENRM  = $0109 ; dto., MSB
.EQU sEATxt = $010A ; Text portion of the akku definition
.EQU sENul  = $0112 ; Null char as stop sign
.EQU sEANm  = $0113 ; Number of stored akkus in Eeprom
;
; next free SRAM location: $0114
;
;
; Reset- and interrupt vectors
; (these are two words in the ATmega16!)
;
.CSEG
.ORG $0000
	rjmp main ; Reset vector
	nop
	reti ; INT0 vector
	nop
	reti ; INT1 vector
	nop
	reti ; TC2Comp vector
	nop
	reti ; TC2Ovf vector
	nop
	reti ; TC1Capt vector
	nop
	rjmp TC1CmpAIsr ; TC1CompA vector
	nop
	rjmp TC1CmpBIsr ; TC1CompB vector
	nop
	reti ; TC1Ovf vector
	nop
	rjmp TC0OvfIsr ; TC0Ovf vector
	nop
	reti ; SPI, STC vector
	nop
	rjmp SioRxCIsr; USARTRxC vector
	nop
	reti ; USARTUdre vector
	nop
	reti ; USARTTxc vector
	nop
	reti ; ADC vector
	nop
	reti ; EE_RDY vector
	nop
	reti ; ANA_COMP vector
	nop
	reti ; TWI vector
	nop
	reti ; INT2 vector
	nop
	reti ; TC0Comp vector
	nop
	reti ; SPM_RDY vector
	nop
;
; TC1 Compare A Int Service routine
; (Reads ADC result and stores it)
;
TC1CmpAIsr:
	in rSreg,SREG ; Save SREG
	sbr rFlg,1<<b64Hz ; set 64 tick flag
	mov rimp,rChCL ; Check counter
	andi rimp,1 ; odd or even channel?
	brne TC1CmpAIsrO ; odd channel
	; even channel
	mov rimp,rChCL ; check counter
	andi rimp,0xF8 ; isolate all but channel info
	brne TC1CmpAIsrE1 ; no start condition
	; TC1 has finished 32 cycles, starts new
	in rimp,ADCL ; read ADC LSB
	st Y,rimp ; store in Sram
	in rimp,ADCH ; read ADC MSB
	std Y+1,rimp ; store in Sram
	rjmp TC1CmpAIsrE3
TC1CmpAIsrE1: ; not starting new
	cpi rimp,0xF8 ; last measurement in channel?
	breq TC1CmpAIsrE2 ; yes, add the last
	; normal measurement, add to sum
	in rimp1,ADCL ; read result LSB
	ld rimp,Y ; read last sum
	add rimp,rimp1 ; add new result
	st Y,rimp ; store in Sram
	in rimp1,ADCH ; read result MSB
	ldd rimp,Y+1 ; read last sum MSB
	adc rimp,rimp1 ; add to sum
	std Y+1,rimp ; store in Sram
	rjmp TC1CmpAIsrE3
TC1CmpAIsrE2: ; the last measurement of the series
	in rimp1,ADCL ; read result
	ld rimp,Y ; read last result
	add rimp,rimp1 ; add to result
	std Y+16,rimp ; store in sum Sram
	in rimp1,ADCH ; read result MSB
	ldd rimp,Y+1 ; load sum result MSB
	adc rimp,rimp1 ; add MSB to result
	std Y+17,rimp ; store in sum Sram MSB
TC1CmpAIsrE3:
	adiw rChCL,1 ; next channel
	mov rimp,rChCL ; copy counter
	andi rimp,0x07 ; isolate channel number
	ori rimp,cAdcV ; Set the voltage Ref bits
	out ADMUX,rimp ; Set next MUX channel
	out SREG,rSreg ; Restore SREG
	reti
;
TC1CmpAIsrO: ; odd channel
	mov rimp,rChCL ; copy channel counter
	andi rimp,0xF8 ; isolate all but channel info
	brne TC1CmpAIsrO1 ; no start condition
	; TC1 has finished 32 cycles, starts new
	in rimp,ADCL ; read ADC LSB
	std Y+8,rimp ; store in Sram
	in rimp,ADCH ; read ADC MSB
	std Y+9,rimp ; store in Sram
	rjmp TC1CmpAIsrO3
TC1CmpAIsrO1: ; not starting new
	cpi rimp,0xF8 ; last measurement in channel?
	breq TC1CmpAIsrO2 ; yes, add the last
	; normal measurement, add to sum
	in rimp1,ADCL ; read result LSB
	ldd rimp,Y+8 ; read last sum
	add rimp,rimp1 ; add new result
	std Y+8,rimp ; store in Sram
	in rimp1,ADCH ; read result MSB
	ldd rimp,Y+9 ; read last sum MSB
	adc rimp,rimp1 ; add to sum
	std Y+9,rimp ; store in Sram
	rjmp TC1CmpAIsrO3
TC1CmpAIsrO2: ; the last measurement of the series
	in rimp1,ADCL ; read result
	ldd rimp,Y+8 ; read last result
	add rimp,rimp1 ; add to result
	std Y+24,rimp ; store in sum Sram
	in rimp1,ADCH ; read result MSB
	ldd rimp,Y+9 ; load sum result MSB
	adc rimp,rimp1 ; add MSB to result
	std Y+25,rimp ; store in sum Sram MSB
TC1CmpAIsrO3:
	adiw YL,2 ; next position in Sram
	adiw rChCL,1 ; next channel
	mov rimp,rChCL ; copy LSB counter
	andi rimp,0x07 ; isolate channel number
	brne TC1CmpAIsrO4 ; not channel 0
	ldi YH,HIGH(sAdcE1) ; pointer to start
	ldi YL,LOW(sAdcE1)
TC1CmpAIsrO4:
	ori rimp,cAdcV ; Set the Ref bits to the selected voltage
	out ADMUX,rimp ; Set next MUX channel
	tst rChCL ; All new?
	brne TC1CmpAIsrO5
	sbr rFlg,1<<b32m ; set flag for 32 cycles
TC1CmpAIsrO5:
	out SREG,rSreg ; Restore SREG
	reti
;
; TC1 Compare B Int Service Routine
;
TC1CmpBIsr:
	sbi ADCSR,ADSC ; start ADC
	reti
;
; TC0 Overflow Int Service Routine
;
Tc0OvfIsr:
	in rsreg,SREG ; Save SREG
	inc rPwmC ; inc counter
	brne Tc0OvfIsr1
	mov rimp,rPwmOut ; Copy the current output
	andi rimp,0xF0 ; Preserve the upper bits
	mov rPwmOut,rimp ; write back
	ldi rimp,0xF0 ; set all upper bits
	eor rimp,rPwmOut ; Invert the upper bits
	swap rimp ; upper to lower bits
	or rPwmOut,rimp
TC0OvfIsr1:
	cp rPwmC,rPwm1S
	brne TC0OvfIsr2
	cbr rPwmOut,1 ; Clear bit for Channel 1
TC0OvfIsr2:
	cp rPwmC,rPwm2S
	brne TC0OvfIsr3
	cbr rPwmOut,2 ; Clear bit for Channel 2
TC0OvfIsr3:
	cp rPwmC,rPwm3S
	brne TC0OvfIsr4
	cbr rPwmOut,4 ; Clear bit for Channel 3
TC0OvfIsr4:
	cp rPwmC,rPwm4s
	brne TC0OvfIsr5
	cbr rPwmOut,8 ; Clear bit for Channel 4
TC0OvfIsr5:
	out PORTC,rPwmOut ; To Port C
	out SREG,rsreg ; Restore SREG
	reti
;
; Uart RxC Interrupt Service Routine
;
SioRxCIsr:
	in rSreg,SREG ; Save SReg
	in rimp,UCSRA ; Read error flags
	andi rimp,(1<<FE)|(1<<DOR)|(1<<PE) ; isolate error bits
	in rimp,UDR ; read character from UART
	breq SioRxCIsr1 ; no errors
	ldi rimp,'*' ; signal an error
	sbrs rFlg,bUartRxLine ; Line buffer blocked?
	out UDR,rimp
	rjmp SioRxCIsr4 ; return from int
SioRxCIsr1:
	sbrc rFlg,bUartRxLine ; Line buffer blocked?
	rjmp SioRxCIsr4 ; yes, ignore character
	out UDR,rimp ; echo the character
	push ZH ; Save Z register
	push ZL
	ldi ZH,HIGH(sUartRxBs) ; Load Position for next RX char
	lds ZL,sUartRxBp
	st Z+,rimp ; save char in buffer
	cpi ZL,LOW(sUartRxBe+1) ; End of buffer?
	brcc SioRxCIsr2 ; Buffer overflow
	sts sUartRxBp,ZL ; Save next pointer position
SioRxCIsr2:
	cpi rimp,cCr ; Carriage Return?
	brne SioRxCIsr3 ; No, go on
	ldi rimp,cLf ; Echo linefeed
	out UDR,rimp
	sbr rFlg,(1<<bUartRxLine) ; Set line complete flag
SioRxCIsr3:
	pop ZL ; Restore Z-register
	pop ZH
SioRxCIsr4:
	out SREG,rSreg ; Restore SREG
	reti ; Return from Int
;
;*************************** Main program *******************
;
; Main program start
;
main:
	ldi rmp,HIGH(RAMEND) ; Set stack pointer
	out SPH,rmp
	ldi rmp,LOW(RAMEND)
	out SPL,rmp
	; Init registers and ram locations
	clr rFlg ; Clear all multi-purpose flags
	clr rFlgD ; Clear the display flag
	ldi rFlgD,0x0F ; enable Lcd line access as default
	; Init ports
	clr rmp ; Set port A bits all input
	out DDRA,rmp
	ldi rmp,0xFF ; Set PORTC all bits output
	out DDRC,rmp
	ldi rmp,0xF2 ; Set Port D Bits 7..4 and 1 to be output
	out DDRD,rmp
	; Init keys
	rcall KeyInit ; Init the key routines
	; Init the Leds
	rcall KeyLedInit ; Init the Leds
	; clear the state flags and system time
	clr rmp
	ldi ZH,HIGH(sState)
	ldi ZL,LOW(sState)
	st Z+,rmp ; sState
	st Z+,rmp ; sTimeM
	st Z+,rmp ; sTimeH
	st Z+,rmp ; sTimeD
	st Z+,rmp ; Lcd Cursor position
	ldi ZH,HIGH(sAdcC) ; Init empty mAh-count
	ldi ZL,LOW(sAdcC)
	ldi rmp,16 ; locations to delete
	clr R0
main1:
	st Z+,R0
	dec rmp
	brne main1
	ldi ZH,HIGH(sCh1UV) ; Init empty akku characteristics
	ldi ZL,LOW(sCh1UV)
	ldi rmp,32
main2:
	st Z+,R0
	dec rmp
	brne main2
	sts sUartCurCh,R0 ; clear Uart channel counter
	; Init the Eeprom list of akkus
	rcall EpInit
	; Init the Uart
	call UartInit ; Init UART receiver+transmitter
	call UartSendOpenText ; Send the opening text
	call UartSendCursor ; Send the cursor over Uart
	; Init the LCD display
	rcall LcdInit ; Init the LCD
	; Init the PWM channels
	clr rPwm1S ; Set startup value for Pwm Channel 0
	clr rPwm2S
	clr rPwm3S
	clr rPwm4S
	clr rPwmOut
	; Init the timers 0 and 1
	ldi rmp,HIGH(cTC1Div) ; TC1: Divider for 64 Hz signal
	out OCR1AH,rmp ; MSB first!
	ldi rmp,LOW(cTC1Div)
	out OCR1AL,rmp ; LSB last!
	ldi rmp,HIGH(cTC1CompB) ; MSB first!
	out OCR1BH,rmp
	ldi rmp,LOW(cTC1CompB) ; LSB last!
	out OCR1BL,rmp
	clr rmp ; TC1: no output pins, no pwm
	out TCCR1A,rmp
	ldi rmp,(1<<WGM12)|(1<<CS11) ; TC1: CTC and Prescaler = 8
	out TCCR1B,rmp
	ldi rmp,(1<<TOIE0)|(1<<OCIE1A)|(1<<OCIE1B) ; TC0 overflow TC1 CompA/B int
	out TIMSK,rmp
	ldi rmp,1<<CS00 ; Set TC0 Prescaler divider to 1
	out TCCR0,rmp
	; Init the ADC
	ldi YH,HIGH(sAdcE1) ; Y is ADC result pointer
	ldi YL,LOW(sAdcE1)
	clr rChCH ; Set channel counter for ADC to 0
	clr rChCL
	ldi rmp,cAdcV ; set ADC voltage, mux to channel 0
	out ADMUX,rmp
	ldi rmp,cStartAdc ; Enable ADC, prescale=128, disable int
	out ADCSR,rmp
	sei ; Enable Ints
loop:
	; Don't use sleep modes here, it will disturb the ADC timing
	tst rFlg ; any flag set?
	breq loop ; no, go to loop again
	ldi rmp,LOW(loop) ; Push return adress to stack
	push rmp
	ldi rmp,HIGH(loop)
	push rmp
	; check the 64 Hz tick from timer 0
	sbrc rFlg,b64Hz ; a tick?
	rjmp Tick64Hz ; read keys
	; check if 32 measure cycles complete and 4 sec are over
	sbrc rFlg,b32m ; Check 4 seconds over
	rjmp Adc32m ; Jump to 32 measurements complete
	; check if results are ready for Uart hex out
	sbrc rFlgD,bURdy
	rjmp DisplHex
	; check if results are ready for LCD display
	sbrc rFlgD,bLRdy
	rjmp DisplLcd
	; Check if a minute is over
	sbrc rFlg,bMin ; minute over flag
	rjmp Minute ; jump to the minute routine
	; Check if a line from the Uart is complete
	sbrs rFlg,bUartRxLine ; Check RX line complete
	ret
	jmp UartRxLine ; yes, answer
;
; 64 Hz Tick
;
Tick64Hz:
	cbr rFlg,1<<b64Hz ; clear flag
	rcall KeyLeds
	rjmp Keys
;
; Include the calculation routines
;
.INCLUDE "akkucalc.asm"
;
; Include the key routines
;
.INCLUDE "akkukey.asm"
;
; Include the LCD-routines
;
.INCLUDE "akkulcd.asm"
;
; Include Uart-RX-routines
;
.INCLUDE "akkuuart.asm"
;
; End of code segment
;
; EEPROM segment, init my akkus
;
.ESEG
;
; Akku definition:
;   Byte 1: number id, must be running from 1 in consecutive order
;   Byte 2: size of the cell, A0(Mono), A1(Baby), A2(AA), A3(AAA)
;   Byte 2 and 3: nominal capacity in mAh, LSB and MSB
;   Byte 4 and 5: number of loads with nominal capacity, LSB and MSB
;   Byte 6 and 7: capacity of loads, remaining mAh from last charge
;   Byte 8 to 16: text description of the cell, exactly 8 chars
;
; Akku 1: AAA, NiMH, Conrad 250185
.DB 0x01,0xA3
.DW 500,4,0
.DB "ConradMH"
;
; Akku 2: AAA, NiMH, Conrad 250185
.DB 0x02,0xA3
.DW 500,4,0
.DB "ConradMH"
;
; Akku 3: AAA, NiMH, Conrad 250185
.DB 0x03,0xA3
.DW 500,4,0
.DB "ConradMH"
;
; Akku 4: AAA, NiMH, Conrad 250185
.DB 0x04,0xA3
.DW 500,4,0
.DB "ConradMH"
;
; Akku 5: AA, NiMH, Pixcell Camera
.DB 0x05,0xA2
.DW 1800,10,0
.DB "PixcelMH"
;
; Akku 6: AA, NiMH, Pixcell Camera
.DB 0x06,0xA2
.DW 1800,10,0
.DB "PixcelMH"
;
; Akku 7: AA, NiMH, Pixcell Camera
.DB 0x07,0xA2
.DW 1800,10,0
.DB "PixcelMH"
;
; Akku 8: AA, NiMH, Pixcell Camera
.DB 0x08,0xA2
.DW 1800,10,0
.DB "PixcelMH"
;
; Akku 9: AA, NiMH, Conrad Voltcraft
.DB 0x09,0xA2
.DW 1700,6,0
.DB "VoltcrMH"
;
; Akku 10: AA, NiMH, Conrad Voltcraft
.DB 0x0A,0xA2
.DW 1700,6,0
.DB "VoltcrMH"
;
; Akku 11: AA, NiMH, Conrad Voltcraft
.DB 0x0B,0xA2
.DW 1700,6,0
.DB "VoltcrMH"
;
; Akku 12: AA, NiMH, Conrad Voltcraft
.DB 0x0C,0xA2
.DW 1700,6,0
.DB "VoltcrMH"
;
; End of accumulator definitions
;